jmail4.5下载地址：http://www.lingchenliang.com/download/JMail45_free.zip

jmail4.5参数简介： 

（1）Body（信件正文） : 字符串 
 如：JMail.Body = "这里可以是用户填写的表单内容，可以取自From。" 
 （2）Charset（字符集，缺省为"US-ASCII"） : 字符串 
 如：JMail.Charset = "US-ASCII" 
 （3）ContentTransferEncoding : 字符串 
 指定内容传送时的编码方式，缺省是"Quoted-Printable" 
 如：JMail.ContentTransferEncoding = "base64" 
 （4）ContentType（信件的contentype. 缺省是"text/plain"） : 字符串 
 如果你以HTML格式发送邮件, 改为"text/html"即可。 
 如：JMail.ContentType = "text/html" 
 （5）Encoding : 字符串 
 设置附件编码方式（缺省是"base64）。可以选择使用的是"base64", "uuencode" or "quoted-printable" 
 如：JMail.Encoding = "base64" 
 （6）Log（Jmail创建的日志，前提logging属性设置为true，见下面） : 字符串 
 如：使用Response.Write( JMail.Log )语句列出日志信息。 
 （7）Logging（是否使用日志） : 布尔型 
 如：JMail.Logging = true 
 （8）Recipients : 字符串 
 只读属性，返回所有收件人。 
 如：Response.Write( "" + JMail.Recipients + "" ); 
 （9）ReplyTo（指定别的回信地址） : 字符串 
 如：JMail.ReplyTo = "57404811@qq.com" 
 （10）Sender（ 发件人的邮件地址） : 字符串 
 如：JMail.Sender = "57404811@qq.com" 
 （11）SenderName（发件人的姓名） : 字符串 
 如：JMail.SenderName = "凌陈亮" 
 （12）ServerAddress（邮件服务器的地址） : 字符串 
 你可以指定多个服务器，用分号点开。可以指定端口号。
 如果serverAddress保持空白，JMail会尝试远程邮件服务器，然后直接发送到服务器上去。 
 如：JMail.ServerAddress = "mail.263.net.cn" 
 （13）Subject（设定邮件的标题，可以取自From。）：字符串 
 如：JMail.Subject = "客户反馈表单" 
 （14）添加文件附件到邮件 
 如：JMail.AddAttachment( "c:\anyfile.zip" ) 
 （15）AddCustomAttachment( FileName, Data ) 
 添加自定义附件。 
 如：JMail.AddCustomAttachment( "anyfile.txt", "Contents of file" ); 
 （16）AddHeader( Header, Value ) 
 添加用户定义的信件标头。 
 如：JMail.AddHeader( "Originating-IP","192.168.1.10" ); 
 （17）AddRecipient（收件人）：字符串 
 如：JMail.AddRecipient( "57404811@qq.com" ); 
 （18）AddRecipientBCC( Email )，密件收件人： 
 如：JMail.AddRecipientBCC( "57404811@qq.com" ); 
 （19）AddRecipientCC( Email ) ，抄送收件人： 
 如：JMail.AddRecipientCC( "57404811@qq.com" ) 
 （20）AddURLAttachment( URL, 文档名) 
 下载并添加一个来自url的附件. 第二个参数"文档名", 用来指定信件收到后的文件名。 
 如：JMail.AddURLAttachment( "http://www.lingchenliang.com/download/JMail45_free.zip", "JMail4.5" ) 
 （21）AppendBodyFromFile( 文件名) ，将文件作为信件正文： 
 如：JMail.AppendBodyFromFile( "c:\anyfile.txt" ) 
 （22）AppendText( Text ) 
 追加信件的正文内容，比如增加问候语或者其它信息。 
 如：JMail.AppendText( "欢迎访问本站！" ) 
 （23）Close() ，强制JMail关闭缓冲的与邮件服务器的连接： 
 如：JMail.Close() 
 （24）Execute() ，执行邮件的发送 
 如：JMail.Execute() 

我自己写的一个jmail发信自定义函数（ASP语言）：

<%

'函数名：gw_sendmail()

'作用：利用Jmail4.5组件发送EMail

'参数：

'tomail：收件人email邮箱地址。

'subject：邮件标题。

'body：邮件内容。

'如果发送成功，函数将返回True，否则返回False

function gw_sendmail(tomail,subject,body)

   dim jmail,smail,smail_pwd,fromname

   smail = "57404811@qq.com" '设定发件人邮箱帐号

   smail_pwd = "***" '设定发件人邮箱密码

   fromname = "**网站" '指定发件人，可为email（如：57404811@qq.com），也可为名称（如：**网站）

   set jmail = Server.createobject("jmail.message") '创建JMAIL对象

   jmail.silent = true '屏蔽例外错误，true表示邮件发送会忽略错误，不将错误信息返回给操作系统。

   jmail.logging = true '使用日志

   jmail.charset = "gb2312"

   jmail.contentType = "text/html"

   jmail.from = smail '设定发件人邮箱

   jmail.fromname = fromname '指定发件人

   jmail.mailserverusername = smail '设定发件人邮箱帐号

   jmail.mailserverpassword = smail_pwd '设定发件人邮箱密码

   jmail.addRecipient tomail '设定收件人邮箱帐号

   jmail.subject = subject '设定邮件的标题

   jmail.body = body '设定邮件的内容

   jmail.returnreceipt=true '当对方收到邮件后发回收条

   'smtp发信服务器名称如：mail.qq.com、smtp.163.com、smtp.163vip.net、smtp.126.com、smtp.sina.com.cn、smtp.gmail.com、smtp.china.com、smtp.sohu.com

   if jmail.send("mail.qq.com")=false then '开始发信并判断发信结果

       gw_sendmail=false '发信失败

   else

       gw_sendmail=true '发信成功

   end if

end function

%>

用户意见/网站留言发送邮件示例（ASP语言）

<%

'用户意见/网站留言发送邮件示例

dim name1,mobile,content,body

name1=trim(request.form("name1"))

mobile=trim(request.form("mobile"))

content=trim(request.form("content"))

body=""

body=body & "<p>留言时间：" & now() & "</p>"

body=body & "<p>留言IP：" & request.ServerVariables("REMOTE_ADDR") & "</p>"

body=body & "<p>客户姓名：" & name1 & "</p>"

body=body & "<p>手机号码：" & mobile & "</p>"

body=body & "<p>留言内容：" & content & "</p>"

if gw_sendmail("57404811@qq.com","**网站留言-" & name1,body)=true then '这里填自己的邮箱

   call alert("发送成功！","/")

else

   call alert("错误：发送失败！","javascript:window.history.back();")

end if

%>

用户注册后自动发送邮件到用户邮箱示例（ASP语言）

<%

'用户注册后自动发送邮件到用户邮箱示例

dim email,username,password,body

email=email '获取注册用户的邮箱

username=username '获取注册用户的用户名

password=password '获取注册用户的用户密码


body=""

body=body & "<p>" & username & "，您好！</p>"

body=body & "<p>欢迎您注册成为**网站（www.***.com）会员，下面是您的注册信息：</p>"

body=body & "<p>用户名：" & username & "</p>"

body=body & "<p>密码：" & password & "</p>"

if gw_sendmail(email,"**网站注册用户信息",body)=true then '这里填会员的邮箱

   call alert("发送成功！","/")

else

   call alert("错误：发送失败！","javascript:window.history.back();")

end if

%>

注：以上两个案例使用了一个自定义函数alert，功能是弹出提示信息，代码如下。

<%

sub alert(msg,url)

   response.write("<script type=""text/javascript"">") & vbcrlf

   response.write("<!--//") & vbcrlf

   response.write("window.alert("""& msg &""");") & vbcrlf

   response.write("window.location.href="""& url &""";") & vbcrlf

   response.write("//-->") & vbcrlf

   response.write("</script>") & vbcrlf

   response.end()

end sub

%>